**Chapter 5. Terraform Tips and Tricks: Loops, If-Statements, Deployment, and Gotchas**

Terraform is a declarative language. As discussed in [Chapter 1](https://www.safaribooksonline.com/library/view/terraform-up-and/9781491977071/ch01.html#why_terraform), infrastructure as code in a declarative language tends to provide a more accurate view of what’s actually deployed than a procedural language, so it’s easier to reason about and makes it easier to keep the codebase small. However, certain types of tasks are more difficult in a declarative language.

For example, since declarative languages typically don’t have for-loops, how do you repeat a piece of logic—such as creating multiple similar resources—without copy and paste? And if the declarative language doesn’t support if-statements, how can you conditionally configure resources, such as creating a Terraform module that can create certain resources for some users of that module but not for others? Finally, how do you express an inherently procedural idea, such as a zero-downtime deployment, in a declarative language?

Fortunately, Terraform provides a few primitives—namely, a meta-parameter called count, a lifecycle block called create\_before\_destroy, a ternary operator, plus a large number of interpolation functions—that allow you to do certain types of loops, if-statements, and zero-downtime deployments. You probably won’t need to use these too often, but when you do, it’s good to be aware of what’s possible and what the gotchas are. Here are the topics I’ll cover in this chapter:

* Loops
* If-statements
* If-else-statements
* Zero-downtime deployment
* Terraform gotchas

**EXAMPLE CODE**

As a reminder, all of the code examples in the book can be found at the following URL: *<https://github.com/brikis98/terraform-up-and-running-code>*.

**Loops**

In [Chapter 2](https://www.safaribooksonline.com/library/view/terraform-up-and/9781491977071/ch02.html#an_intro_to_terraform_syntax), you created an IAM user by clicking around the AWS console. Now that you have this user, you can create and manage all future IAM users with Terraform. Consider the following Terraform code, which should live in *live/global/iam/main.tf*:

**provider** "aws" {

region = "us-east-1"

}

**resource** "aws\_iam\_user" "example" {

name = "neo"

}

This code uses the aws\_iam\_user resource to create a single new IAM user. What if you wanted to create three IAM users? In a general-purpose programming language, you’d probably use a for-loop:

*# This is just pseudo code. It won't actually work in Terraform.*

for i = 0; i < 3; i++ {

**resource** "aws\_iam\_user" "example" {

name = "neo"

}

}

Terraform does not have for-loops or other traditional procedural logic built into the language, so this syntax will not work. However, almost every Terraform resource has a meta-parameter you can use called count. This parameter defines how many copies of the resource to create. Therefore, you can create three IAM users as follows:

**resource** "aws\_iam\_user" "example" {

count = 3

name = "neo"

}

One problem with this code is that all three IAM users would have the same name, which would cause an error, since usernames must be unique. If you had access to a standard for-loop, you might use the index in the for loop, i, to give each user a unique name:

*# This is just pseudo code. It won't actually work in Terraform.*

for i = 0; i < 3; i++ {

**resource** "aws\_iam\_user" "example" {

name = "neo.${i}"

}

}

To accomplish the same thing in Terraform, you can use count.index to get the index of each “iteration” in the “loop”:

**resource** "aws\_iam\_user" "example" {

count = 3

name = "neo.${count.index}"

}

If you run the plan command on the preceding code, you will see that Terraform wants to create three IAM users, each with a different name (“neo.0”, “neo.1”, “neo.2”):

+ aws\_iam\_user.example.0

arn: "<computed>"

force\_destroy: "false"

name: "neo.0"

path: "/"

unique\_id: "<computed>"

+ aws\_iam\_user.example.1

arn: "<computed>"

force\_destroy: "false"

name: "neo.1"

path: "/"

unique\_id: "<computed>"

+ aws\_iam\_user.example.2

arn: "<computed>"

force\_destroy: "false"

name: "neo.2"

path: "/"

unique\_id: "<computed>"

Plan: 3 to add, 0 to change, 0 to destroy.

Of course, a username like “neo.0” isn’t particularly usable. If you combine count.index with some interpolation functions built into Terraform, you can customize each “iteration” of the “loop” even more.

For example, you could define all of the IAM usernames you want in an input variable in *live/global/iam/vars.tf*:

**variable** "user\_names" {

description = "Create IAM users with these names"

type = "list"

default = ["neo", "trinity", "morpheus"]

}

If you were using a general-purpose programming language with loops and arrays, you would configure each IAM user to use a different name by looking up index i in the array var.user\_names:

*# This is just pseudo code. It won't actually work in Terraform.*

for i = 0; i < 3; i++ {

**resource** "aws\_iam\_user" "example" {

name = "${vars.user\_names[i]}"

}

}

In Terraform, you can accomplish the same thing by using count and two interpolation functions, element and length:

"${element(LIST, INDEX)}"

"${length(LIST)}"

The element function returns the item located at INDEX in the given LIST.[1](https://www.safaribooksonline.com/library/view/terraform-up-and/9781491977071/ch05.html#idm140207901199520) The length function returns the number of items in LIST (it also works with strings and maps). Putting these together, you get:

**resource** "aws\_iam\_user" "example" {

count = "${length(var.user\_names)}"

name = "${element(var.user\_names, count.index)}"

}

Now when you run the plan command, you’ll see that Terraform wants to create three IAM users, each with a unique name:

+ aws\_iam\_user.example.0

arn: "<computed>"

force\_destroy: "false"

name: "neo"

path: "/"

unique\_id: "<computed>"

+ aws\_iam\_user.example.1

arn: "<computed>"

force\_destroy: "false"

name: "trinity"

path: "/"

unique\_id: "<computed>"

+ aws\_iam\_user.example.2

arn: "<computed>"

force\_destroy: "false"

name: "morpheus"

path: "/"

unique\_id: "<computed>"

Plan: 3 to add, 0 to change, 0 to destroy.

Note that once you’ve used count on a resource, it becomes a list of resources, rather than just one resource. Since aws\_iam\_user.example is now a list of IAM users, instead of using the standard syntax to read an attribute from that resource (TYPE.NAME.ATTRIBUTE), you have to specify which IAM user you’re interested in by specifying its index in the list:

"${TYPE.NAME.INDEX.ATTRIBUTE}"

For example, if you wanted to provide the Amazon Resource Name (ARN) of one of the IAM users as an output variable, you would need to do the following:

output "neo\_arn" {

value = "${aws\_iam\_user.example.0.arn}"

}

If you want the ARNs of *all* the IAM users, you need to use the *splat* character, “\*”, instead of the index:

"${aws\_iam\_user.example.\*.arn}"

When you use the splat character, you get back a list, so you need to wrap the output variable with brackets:

output "all\_arns" {

value = ["${aws\_iam\_user.example.\*.arn}"]

}

When you run the apply command, the all\_arns output will contain the list of ARNs:

> terraform apply

(...)

Apply complete! Resources: 3 added, 0 changed, 0 destroyed.

Outputs:

all\_arns = [

arn:aws:iam::123456789012:user/neo,

arn:aws:iam::123456789012:user/trinity,

arn:aws:iam::123456789012:user/morpheus

]

Note that since the splat syntax returns a list, you can combine it with other interpolation functions, such as element. For example, let’s say you wanted to give each of these IAM users read-only access to EC2. You may remember from [Chapter 2](https://www.safaribooksonline.com/library/view/terraform-up-and/9781491977071/ch02.html#an_intro_to_terraform_syntax) that by default, new IAM users have no permissions whatsoever, and that to grant permissions, you can attach IAM policies to those IAM users. An IAM policy is a JSON document:

{

**"Statement"**: [

{

**"Effect"**: "Allow",

**"Action"**: ["ec2:Describe\*"],

**"Resource"**: ["\*"]

}

]

}

An IAM policy consists of one or more *statements*, each of which specifies an *effect* (either “Allow” or “Deny”), on one or more *actions* (e.g., "ec2:Describe\*" allows all API calls to EC2 that start with the name "Describe"), on one or more *resources* (e.g., "\*" means “all resources”). Although you can define IAM policies in JSON, Terraform also provides a handy data source called the aws\_iam\_policy\_document that gives you a more concise way to define the same IAM policy:

data "aws\_iam\_policy\_document" "ec2\_read\_only" {

statement {

effect = "Allow"

actions = ["ec2:Describe\*"]

resources = ["\*"]

}

}

To create a new managed IAM policy from this document, you need to use the aws\_iam\_policy resource and set its policy parameter to the JSON output of the aws\_iam\_policy\_document you just created:

**resource** "aws\_iam\_policy" "ec2\_read\_only" {

name = "ec2-read-only"

policy = "${data.aws\_iam\_policy\_document.ec2\_read\_only.json}"

}

Finally, to attach the IAM policy to your new IAM users, you use the aws\_iam\_user\_policy\_attachment resource:

**resource** "aws\_iam\_user\_policy\_attachment" "ec2\_access" {

count = "${length(var.user\_names)}"

user = "${element(aws\_iam\_user.example.\*.name, count.index)}"

policy\_arn = "${aws\_iam\_policy.ec2\_read\_only.arn}"

}

This code uses the count parameter to “loop” over each of your IAM users and the element interpolation function to select each user’s ARN from the list returned by aws\_iam\_user.example.\*.arn.

**If-Statements**

Using count lets you do a basic loop. If you’re clever, you can use the same mechanism to do a basic if-statement as well. Let’s start by looking at simple if-statements in the next section and then move on to more complicated ones in the section after that.

**Simple If-Statements**

In [Chapter 4](https://www.safaribooksonline.com/library/view/terraform-up-and/9781491977071/ch04.html#how_to_create_reusable_infrastructure), you created a Terraform module that could be used as “blueprint” for deploying web server clusters. The module created an Auto Scaling Group (ASG), Elastic Load Balancer (ELB), security groups, and a number of other resources. One thing the module did *not* create was the auto scaling schedule. Since you only want to scale the cluster out in production, you defined the aws\_autoscaling\_schedule resources directly in the production configurations under *live/prod/services/webserver-cluster/main.tf*. Is there a way you could define the aws\_autoscaling\_schedule resources in the webserver-cluster module and conditionally create them for some users of the module and not create them for others?

Let’s give it a shot. The first step is to add a boolean input variable in *modules/services/webserver-cluster/vars.tf* that can be used to specify whether the module should enable auto scaling:

**variable** "enable\_autoscaling" {

description = "If set to true, enable auto scaling"

}

Now, if you had a general-purpose programming language, you could use this input variable in an if-statement:

*# This is just pseudo code. It won't actually work in Terraform.*

if ${var.enable\_autoscaling} {

**resource** "aws\_autoscaling\_schedule" "scale\_out\_during\_business\_hours" {

scheduled\_action\_name = "scale-out-during-business-hours"

min\_size = 2

max\_size = 10

desired\_capacity = 10

recurrence = "0 9 \* \* \*"

autoscaling\_group\_name = "${aws\_autoscaling\_group.example.name}"

}

**resource** "aws\_autoscaling\_schedule" "scale\_in\_at\_night" {

scheduled\_action\_name = "scale-in-at-night"

min\_size = 2

max\_size = 10

desired\_capacity = 2

recurrence = "0 17 \* \* \*"

autoscaling\_group\_name = "${aws\_autoscaling\_group.example.name}"

}

}

Terraform doesn’t support if-statements, so this code won’t work. However, you can accomplish the same thing by using the count parameter and taking advantage of two properties:

1. In Terraform, if you set a variable to a boolean true (that is, the word true without any quotes around it), it will be coerced into a 1, and if you set it to a boolean false, it will be coerced into a 0.
2. If you set count to 1 on a resource, you get one copy of that resource; if you set count to 0, that resource is not created at all.

Putting these two ideas together, you can update the webserver-cluster module as follows:

**resource** "aws\_autoscaling\_schedule" "scale\_out\_during\_business\_hours" {

count = "${var.enable\_autoscaling}"

scheduled\_action\_name = "scale-out-during-business-hours"

min\_size = 2

max\_size = 10

desired\_capacity = 10

recurrence = "0 9 \* \* \*"

autoscaling\_group\_name = "${aws\_autoscaling\_group.example.name}"

}

**resource** "aws\_autoscaling\_schedule" "scale\_in\_at\_night" {

count = "${var.enable\_autoscaling}"

scheduled\_action\_name = "scale-in-at-night"

min\_size = 2

max\_size = 10

desired\_capacity = 2

recurrence = "0 17 \* \* \*"

autoscaling\_group\_name = "${aws\_autoscaling\_group.example.name}"

}

If var.enable\_autoscaling is true, the count parameter for each of the aws\_autoscaling\_schedule resources will be set to 1, so one of each will be created. If var.enable\_autoscaling is false, the count parameter for each of the aws\_autoscaling\_schedule resources will be set to 0, so neither one will be created. This is exactly the conditional logic you want!

You can now update the usage of this module in staging (in *live/stage/services/webserver-cluster/main.tf*) to disable auto scaling by setting enable\_autoscaling to false:

**module** "webserver\_cluster" {

source = "../../../../modules/services/webserver-cluster"

cluster\_name = "webservers-stage"

db\_remote\_state\_bucket = "(YOUR\_BUCKET\_NAME)"

db\_remote\_state\_key = "stage/data-stores/mysql/terraform.tfstate"

instance\_type = "t2.micro"

min\_size = 2

max\_size = 2

enable\_autoscaling = **false**

}

Similarly, you can update the usage of this module in production (in *live/prod/services/webserver-cluster/main.tf*) to enable auto scaling by setting enable\_autoscaling to true (make sure to also remove the custom aws\_autoscaling\_schedule resources that were in the production environment from [Chapter 4](https://www.safaribooksonline.com/library/view/terraform-up-and/9781491977071/ch04.html#how_to_create_reusable_infrastructure)):

**module** "webserver\_cluster" {

source = "../../../../modules/services/webserver-cluster"

cluster\_name = "webservers-prod"

db\_remote\_state\_bucket = "(YOUR\_BUCKET\_NAME)"

db\_remote\_state\_key = "prod/data-stores/mysql/terraform.tfstate"

instance\_type = "m4.large"

min\_size = 2

max\_size = 10

enable\_autoscaling = **true**

}

**More Complicated If-Statements**

This approach works well if the user passes an explicit boolean value to your module, but what do you do if the boolean is the result of a more complicated comparison, such as string equality? To handle more complicated cases, you can again use the count parameter, but this time, rather than setting it to a boolean variable, you set it to the value returned by a *conditional*. Conditionals in Terraform use the same *ternary syntax* available in many programming languages:

"${CONDITION ? TRUEVAL : FALSEVAL}"

For example, a more verbose way to do the simple if-statement from the previous section is as follows:

count = "${var.enable\_autoscaling ? 1 : 0}"

Let’s go through a more complicated example. Imagine that as part of the webserver-cluster module, you wanted to create a set of CloudWatch alarms. A *CloudWatch alarm* can be configured to notify you via a variety of mechanisms (e.g., email, text message) if a specific metric exceeds a predefined threshold. For example, here is how you could use the aws\_cloudwatch\_metric\_alarm resource in *modules/services/webserver-cluster/main.tf* to create an alarm that goes off if the average CPU utilization in the cluster is over 90% during a 5-minute period:

**resource** "aws\_cloudwatch\_metric\_alarm" "high\_cpu\_utilization" {

alarm\_name = "${var.cluster\_name}-high-cpu-utilization"

namespace = "AWS/EC2"

metric\_name = "CPUUtilization"

dimensions = {

AutoScalingGroupName = "${aws\_autoscaling\_group.example.name}"

}

comparison\_operator = "GreaterThanThreshold"

evaluation\_periods = 1

period = 300

statistic = "Average"

threshold = 90

unit = "Percent"

}

This works fine for a CPU Utilization alarm, but what if you wanted to add another alarm that goes off when CPU credits are low?[2](https://www.safaribooksonline.com/library/view/terraform-up-and/9781491977071/ch05.html#idm140207900413392) Here is a CloudWatch alarm that goes off if your web server cluster is almost out of CPU credits:

**resource** "aws\_cloudwatch\_metric\_alarm" "low\_cpu\_credit\_balance" {

alarm\_name = "${var.cluster\_name}-low-cpu-credit-balance"

namespace = "AWS/EC2"

metric\_name = "CPUCreditBalance"

dimensions = {

AutoScalingGroupName = "${aws\_autoscaling\_group.example.name}"

}

comparison\_operator = "LessThanThreshold"

evaluation\_periods = 1

period = 300

statistic = "Minimum"

threshold = 10

unit = "Count"

}

The catch is that CPU credits only apply to tXXX Instances (e.g., t2.micro, t2.medium, etc). Larger instance types (e.g., m4.large) don’t use CPU credits and don’t report a CPUCreditBalance metric, so if you create such an alarm for those instances, the alarm will always be stuck in the “INSUFFICIENT\_DATA” state. Is there a way to create an alarm only if var.instance\_type starts with the letter “t”?

You could add a new boolean input variable called var.is\_t2\_instance, but that would be redundant with var.instance\_type, and you’d most likely forget to update one when updating the other. A better alternative is to use a conditional:

**resource** "aws\_cloudwatch\_metric\_alarm" "low\_cpu\_credit\_balance" {

count = "${format("%.1s", var.instance\_type) == "t" ? 1 : 0}"

alarm\_name = "${var.cluster\_name}-low-cpu-credit-balance"

namespace = "AWS/EC2"

metric\_name = "CPUCreditBalance"

dimensions = {

AutoScalingGroupName = "${aws\_autoscaling\_group.example.name}"

}

comparison\_operator = "LessThanThreshold"

evaluation\_periods = 1

period = 300

statistic = "Minimum"

threshold = 10

unit = "Count"

}

The alarm code is the same as before, except for the relatively complicated count parameter:

count = "${format("%.1s", var.instance\_type) == "t" ? 1 : 0}"

This code uses the format function to extract just the first character from var.instance\_type. If that character is a “t” (e.g., t2.micro), it sets the count to 1; otherwise, it sets the count to 0. This way, the alarm is only created for instance types that actually have a CPUCreditBalance metric.

**If-Else-Statements**

Now that you know how to do an if-statement, what about an if-else-statement? Let’s again start by looking at simple if-else-statements in the next section and move on to more complicated ones in the section after that.

**Simple If-Else-Statements**

Earlier in this chapter, you created several IAM users with read-only access to EC2. Imagine that you wanted to give one of these users, neo, access to CloudWatch as well, but to allow the person applying the Terraform configurations to decide if neo got only read access or both read and write access. This is a slightly contrived example, but it makes it easy to demonstrate a simple type of if-else-statement, where all that matters is that one of the if or else branches gets executed, and the rest of the Terraform code doesn’t need to know which one.

Here is an IAM policy that allows read-only access to CloudWatch:

**resource** "aws\_iam\_policy" "cloudwatch\_read\_only" {

name = "cloudwatch-read-only"

policy = "${data.aws\_iam\_policy\_document.cloudwatch\_read\_only.json}"

}

data "aws\_iam\_policy\_document" "cloudwatch\_read\_only" {

statement {

effect = "Allow"

actions = ["cloudwatch:Describe\*", "cloudwatch:Get\*", "cloudwatch:List\*"]

resources = ["\*"]

}

}

And here is an IAM policy that allows full (read and write) access to CloudWatch:

**resource** "aws\_iam\_policy" "cloudwatch\_full\_access" {

name = "cloudwatch-full-access"

policy = "${data.aws\_iam\_policy\_document.cloudwatch\_full\_access.json}"

}

data "aws\_iam\_policy\_document" "cloudwatch\_full\_access" {

statement {

effect = "Allow"

actions = ["cloudwatch:\*"]

resources = ["\*"]

}

}

The goal is to attach one of these IAM policies to neo, based on the value of a new input variable called give\_neo\_cloudwatch\_full\_access:

**variable** "give\_neo\_cloudwatch\_full\_access" {

description = "If true, neo gets full access to CloudWatch"

}

If you were using a general-purpose programming language, you might write an if-else-statement that looks like this:

*# This is just pseudo code. It won't actually work in Terraform.*

if ${var.give\_neo\_cloudwatch\_full\_access} {

**resource** "aws\_iam\_user\_policy\_attachment" "neo\_cloudwatch\_full\_access" {

user = "${aws\_iam\_user.example.0.name}"

policy\_arn = "${aws\_iam\_policy.cloudwatch\_full\_access.arn}"

}

} else {

**resource** "aws\_iam\_user\_policy\_attachment" "neo\_cloudwatch\_read\_only" {

user = "${aws\_iam\_user.example.0.name}"

policy\_arn = "${aws\_iam\_policy.cloudwatch\_read\_only.arn}"

}

}

To do this in Terraform, you can again use the count parameter and a boolean, but this time, you also need to take advantage of the fact that Terraform allows simple math in interpolations:

**resource** "aws\_iam\_user\_policy\_attachment" "neo\_cloudwatch\_full\_access" {

count = "${var.give\_neo\_cloudwatch\_full\_access}"

user = "${aws\_iam\_user.example.0.name}"

policy\_arn = "${aws\_iam\_policy.cloudwatch\_full\_access.arn}"

}

**resource** "aws\_iam\_user\_policy\_attachment" "neo\_cloudwatch\_read\_only" {

count = "${1 - var.give\_neo\_cloudwatch\_full\_access}"

user = "${aws\_iam\_user.example.0.name}"

policy\_arn = "${aws\_iam\_policy.cloudwatch\_read\_only.arn}"

}

This code contains two aws\_iam\_user\_policy\_attachment resources. The first one, which attaches the CloudWatch full access permissions, sets its count parameter to var.give\_neo\_cloudwatch\_full\_access, so this resource only gets created if var.give\_neo\_cloudwatch\_full\_access is true (this is the if-clause). The second one, which attaches the CloudWatch read-only permissions, sets its count parameter to 1 - var.give\_neo\_cloudwatch\_full\_access, so it will have the inverse behavior, and only be created if var.give\_neo\_cloudwatch\_full\_access is false (this is the else-clause).

**More Complicated If-Else-Statements**

This approach works well if your Terraform code doesn’t need to know which of the if or else clauses actually got executed. But what if you need to access some output attribute on the resource that comes out of the if or else clause? For example, what if you wanted to offer two different User Data scripts in the webserver-cluster module and allow users to pick which one gets executed? Currently, the webserver-cluster module pulls in the *user-data.sh* script via a template\_file data source:

data "template\_file" "user\_data" {

template = "${file("${path.module}/user-data.sh")}"

vars {

server\_port = "${var.server\_port}"

db\_address = "${data.terraform\_remote\_state.db.address}"

db\_port = "${data.terraform\_remote\_state.db.port}"

}

}

The current *user-data.sh* script looks like this:

*#!/bin/bash*

cat > index.html <<EOF

<h1>Hello, World</h1>

<p>DB address: ${db\_address}</p>

<p>DB port: ${db\_port}</p>

EOF

nohup busybox httpd -f -p "${server\_port}" &

Now, imagine that you wanted to allow some of your web server clusters to use this alternative, shorter script, called *user-data-new.sh*:

*#!/bin/bash*

echo "Hello, World, v2" > index.html

nohup busybox httpd -f -p "${server\_port}" &

To use this script, you need a new template\_file data source:

data "template\_file" "user\_data\_new" {

template = "${file("${path.module}/user-data-new.sh")}"

vars {

server\_port = "${var.server\_port}"

}

}

The question is, how can you allow the user of the webserver-cluster module to pick from one of these User Data scripts? As a first step, you could add a new boolean input variable in *modules/services/webserver-cluster/vars.tf*:

**variable** "enable\_new\_user\_data" {

description = "If set to true, use the new User Data script"

}

If you were using a general-purpose programming language, you could add an if-else-statement to the launch configuration to pick between the two User Data template\_file options as follows:

*# This is just pseudo code. It won't actually work in Terraform.*

**resource** "aws\_launch\_configuration" "example" {

image\_id = "ami-40d28157"

instance\_type = "${var.instance\_type}"

security\_groups = ["${aws\_security\_group.instance.id}"]

if ${var.enable\_new\_user\_data} {

user\_data = "${data.template\_file.user\_data\_new.rendered}"

} else {

user\_data = "${data.template\_file.user\_data.rendered}"

}

lifecycle {

create\_before\_destroy = **true**

}

}

To make this work with real Terraform code, you first need to use the if-else-statement trick from before to ensure that only one of the template\_file data sources is actually created:

data "template\_file" "user\_data" {

count = "${1 - var.enable\_new\_user\_data}"

template = "${file("${path.module}/user-data.sh")}"

vars {

server\_port = "${var.server\_port}"

db\_address = "${data.terraform\_remote\_state.db.address}"

db\_port = "${data.terraform\_remote\_state.db.port}"

}

}

data "template\_file" "user\_data\_new" {

count = "${var.enable\_new\_user\_data}"

template = "${file("${path.module}/user-data-new.sh")}"

vars {

server\_port = "${var.server\_port}"

}

}

If var.enable\_new\_user\_data is true, then data.template\_file.user\_data\_new will be created and data.template\_file.user\_data will not; if it’s false, it’ll be the other way around. All you have to do now is to set the user\_data parameter of the aws\_launch\_configuration resource to the template\_file that actually exists. To do this, you can take advantage of the concat interpolation function:

"${concat(LIST1, LIST2, ...)}"

The concat function combines two or more lists into a single list. Here is how you can combine it with the element function to select the proper template\_file:

**resource** "aws\_launch\_configuration" "example" {

image\_id = "ami-40d28157"

instance\_type = "${var.instance\_type}"

security\_groups = ["${aws\_security\_group.instance.id}"]

user\_data = "${element(

concat(data.template\_file.user\_data.\*.rendered,

data.template\_file.user\_data\_new.\*.rendered),

0)}"

lifecycle {

create\_before\_destroy = **true**

}

}

Let’s break the large value for the user\_data parameter down. First, take a look at the inner part:

concat(data.template\_file.user\_data.\*.rendered,

data.template\_file.user\_data\_new.\*.rendered)

Note that the two template\_file resources are both lists, as they both use the count parameter. One of these lists will be of length 1 and the other of length 0, depending on the value of var.enable\_new\_user\_data. The preceding code uses the concat function to combine these two lists into a single list, which will be of length 1. Now consider the outer part:

user\_data = "${element(<INNER>, 0)}"

This code simply takes the list returned by the inner part, which will be of length 1, and uses the element function to extract that one value.

You can now try out the new User Data script in the staging environment by setting the enable\_new\_user\_data parameter to true in *live/stage/services/webserver-cluster/main.tf*:

**module** "webserver\_cluster" {

source = "../../../../modules/services/webserver-cluster"

cluster\_name = "webservers-stage"

db\_remote\_state\_bucket = "(YOUR\_BUCKET\_NAME)"

db\_remote\_state\_key = "stage/data-stores/mysql/terraform.tfstate"

instance\_type = "t2.micro"

min\_size = 2

max\_size = 2

enable\_autoscaling = **false**

enable\_new\_user\_data = **true**

}

In the production environment, you can stick with the old version of the script by setting enable\_new\_user\_data to false in *live/prod/services/webserver-cluster/main.tf*:

**module** "webserver\_cluster" {

source = "../../../../modules/services/webserver-cluster"

cluster\_name = "webservers-prod"

db\_remote\_state\_bucket = "(YOUR\_BUCKET\_NAME)"

db\_remote\_state\_key = "prod/data-stores/mysql/terraform.tfstate"

instance\_type = "m4.large"

min\_size = 2

max\_size = 10

enable\_autoscaling = **true**

enable\_new\_user\_data = **false**

}

Using count and interpolation functions to simulate if-else-statements is a bit of a hack, but it’s one that works fairly well, and as you can see from the code, it allows you to conceal lots of complexity from your users so that they get to work with a clean and simple API.

**Zero-Downtime Deployment**

Now that your module has a clean and simple API for deploying a web server cluster, an important question to ask is, how do you update that cluster? That is, when you have made changes to your code, how do you deploy a new AMI across the cluster? And how do you do it without causing downtime for your users?

The first step is to expose the AMI as an input variable in *modules/services/webserver-cluster/vars.tf*. In real-world examples, this is all you would need, as the actual web server code would be defined in the AMI. However, in the simplified examples in this book, all of the web server code is actually in the User Data script, and the AMI is just a vanilla Ubuntu image. Switching to a different version of Ubuntu won’t make for much of a demonstration, so in addition to the new AMI input variable, you can also add an input variable to control the text the User Data script returns from its one-liner HTTP server:

**variable** "ami" {

description = "The AMI to run in the cluster"

default = "ami-40d28157"

}

**variable** "server\_text" {

description = "The text the web server should return"

default = "Hello, World"

}

Earlier in the chapter, to practice with if-else-statements, you created two User Data scripts. Let’s consolidate that back down to one to keep things simple. First, in *modules/services/webserver-cluster/vars.tf*, remove the enable\_new\_user\_data input variable. Second, in *modules/services/webserver-cluster/main.tf*, remove the template\_file resource called user\_data\_new. Third, in the same file, update the other template\_file resource, called user\_data, to no longer use the enable\_new\_user\_data input variable, and to add the new server\_text input variable to its vars block:

data "template\_file" "user\_data" {

template = "${file("${path.module}/user-data.sh")}"

vars {

server\_port = "${var.server\_port}"

db\_address = "${data.terraform\_remote\_state.db.address}"

db\_port = "${data.terraform\_remote\_state.db.port}"

server\_text = "${var.server\_text}"

}

}

Now you need to update the *modules/services/webserver-cluster/user-data.sh* Bash script to use this server\_text variable in the <h1> tag it returns:

*#!/bin/bash*

cat > index.html <<EOF

<h1>${server\_text}</h1>

<p>DB address: ${db\_address}</p>

<p>DB port: ${db\_port}</p>

EOF

nohup busybox httpd -f -p "${server\_port}" &

Finally, find the launch configuration in *modules/services/webserver-cluster/main.tf*, set its user\_data parameter to the remaining template\_file (the one called user\_data), and set its ami parameter to the new ami input variable:

**resource** "aws\_launch\_configuration" "example" {

image\_id = "${var.ami}"

instance\_type = "${var.instance\_type}"

security\_groups = ["${aws\_security\_group.instance.id}"]

user\_data = "${data.template\_file.user\_data.rendered}"

lifecycle {

create\_before\_destroy = **true**

}

}

Now, in the staging environment, in *live/stage/services/webserver-cluster/main.tf*, you can set the new ami and server\_text parameters and remove the enable\_new\_user\_data parameter:

**module** "webserver\_cluster" {

source = "../../../../modules/services/webserver-cluster"

ami = "ami-40d28157"

server\_text = "New server text"

cluster\_name = "webservers-stage"

db\_remote\_state\_bucket = "(YOUR\_BUCKET\_NAME)"

db\_remote\_state\_key = "stage/data-stores/mysql/terraform.tfstate"

instance\_type = "t2.micro"

min\_size = 2

max\_size = 2

enable\_autoscaling = **false**

}

This code uses the same Ubuntu AMI, but changes the server\_text to a new value. If you run the plan command, you should see something like the following (I’ve omitted some of the output for clarity):

~ module.webserver\_cluster.aws\_autoscaling\_group.example

launch\_configuration:

"terraform-2016182624wu" => "${aws\_launch\_configuration.example.id}"

-/+ module.webserver\_cluster.aws\_launch\_configuration.example

ebs\_block\_device.#: "0" => "<computed>"

ebs\_optimized: "false" => "<computed>"

enable\_monitoring: "true" => "true"

image\_id: "ami-40d28157" => "ami-40d28157"

instance\_type: "t2.micro" => "t2.micro"

key\_name: "" => "<computed>"

name: "terraform-2016wu" => "<computed>"

root\_block\_device.#: "0" => "<computed>"

security\_groups.#: "1" => "1"

user\_data: "416115339b" => "3bab6ede8dc" (forces new resource)

Plan: 1 to add, 1 to change, 1 to destroy.

As you can see, Terraform wants to make two changes: first, replace the old launch configuration with a new one that has the updated user\_data, and second, modify the Auto Scaling Group to reference the new launch configuration. The problem is that merely referencing the new launch configuration will have no effect until the Auto Scaling Group launches new EC2 Instances. So how do you tell the Auto Scaling Group to deploy new Instances?

One option is to destroy the ASG (e.g., by running terraform destroy) and then re-create it (e.g., by running terraform apply). The problem is that after you delete the old ASG, your users will experience downtime until the new ASG comes up. What you want to do instead is a *zero-downtime deployment*. The way to accomplish that is to create the replacement ASG first and then destroy the original one. As it turns out, this is exactly what the create\_before\_destroy lifecycle setting does!

Here’s how you can take advantage of this lifecycle setting to get a zero-downtime deployment:[3](https://www.safaribooksonline.com/library/view/terraform-up-and/9781491977071/ch05.html#idm140207899037600)

1. Configure the name parameter of the ASG to depend directly on the name of the launch configuration. That way, each time the launch configuration changes (which it will when you update the AMI or User Data), Terraform will try to replace the ASG.
2. Set the create\_before\_destroy parameter of the ASG to true, so each time Terraform tries to replace it, it will create the replacement before destroying the original.
3. Set the min\_elb\_capacity parameter of the ASG to the min\_size of the cluster so that Terraform will wait for at least that many servers from the new ASG to register in the ELB before it’ll start destroying the original ASG.

Here is what the updated aws\_autoscaling\_group resource should look like in *modules/services/webserver-cluster/main.tf*:

**resource** "aws\_autoscaling\_group" "example" {

name = "${var.cluster\_name}-${aws\_launch\_configuration.example.name}"

launch\_configuration = "${aws\_launch\_configuration.example.id}"

availability\_zones = ["${data.aws\_availability\_zones.all.names}"]

load\_balancers = ["${aws\_elb.example.name}"]

health\_check\_type = "ELB"

min\_size = "${var.min\_size}"

max\_size = "${var.max\_size}"

min\_elb\_capacity = "${var.min\_size}"

lifecycle {

create\_before\_destroy = **true**

}

tag {

key = "Name"

value = "${var.cluster\_name}"

propagate\_at\_launch = **true**

}

}

As you may remember, a gotcha with the create\_before\_destroy parameter is that if you set it to true on a resource R, you also have to set it to true on every resource that R depends on. In the web server cluster module, the aws\_autoscaling\_group resource depends on one other resource, the aws\_elb. The aws\_elb, in turn, depends on one other resource, an aws\_security\_group. Set create\_before\_destroy to true on both of those resources.

If you rerun the plan command, you’ll now see something that looks like this (I’ve omitted some of the output for clarity):

-/+ module.webserver\_cluster.aws\_autoscaling\_group.example

availability\_zones.#: "4" => "4"

default\_cooldown: "300" => "<computed>"

desired\_capacity: "2" => "<computed>"

force\_delete: "false" => "false"

health\_check\_type: "ELB" => "ELB"

launch\_configuration: "terraform-20161wu" =>

"${aws\_launch\_configuration.example.id}"

max\_size: "2" => "2"

min\_elb\_capacity: "" => "2"

min\_size: "2" => "2"

name: "tf-asg-200170wox" => "${var.cluster\_name}

-${aws\_launch\_configuration.example.name}" (forces new resource)

protect\_from\_scale\_in: "false" => "false"

tag.#: "1" => "1"

tag.2305202985.key: "Name" => "Name"

tag.2305202985.value: "webservers-stage" => "webservers-stage"

vpc\_zone\_identifier.#: "1" => "<computed>"

wait\_for\_capacity\_timeout: "10m" => "10m"

-/+ module.webserver\_cluster.aws\_launch\_configuration.example

ebs\_block\_device.#: "0" => "<computed>"

ebs\_optimized: "false" => "<computed>"

enable\_monitoring: "true" => "true"

image\_id: "ami-40d28157" => "ami-40d28157"

instance\_type: "t2.micro" => "t2.micro"

key\_name: "" => "<computed>"

name: "terraform-20161118182404wu" => "<computed>"


root\_block\_device.#: "0" => "<computed>"

security\_groups.#: "1" => "1"

user\_data: "416115339b" => "3bab6edc" (forces new resource)


Plan: 2 to add, 2 to change, 2 to destroy.

The key thing to notice is that the aws\_autoscaling\_group resource now says “forces new resource” next to its name parameter, which means Terraform will replace it with a new Auto Scaling Group running the new version of your code (or new version of your User Data). Run the apply command to kick off the deployment, and while it runs, consider how the process works. You start with your original ASG running, say, v1 of your code (Figure 5-1).




*Figure 5-1. Initially, you have the original ASG running v1 of your code*

You make an update to some aspect of the launch configuration, such as switching to an AMI that contains v2 of your code, and run the apply command. This forces Terraform to start deploying a new ASG with v2 of your code (Figure 5-2).




*Figure 5-2. Terraform begins deploying the new ASG with v2 of your code*

After a minute or two, the servers in the new ASG have booted, connected to the database, and registered in the ELB. At this point, both the v1 and v2 versions of your app will be running simultaneously, and which one users see depends on where the ELB happens to route them (Figure 5-3).




*Figure 5-3. The servers in the new ASG boot up, connect to the DB, register in the ELB, and start serving traffic*

Once min\_elb\_capacity servers from the v2 ASG cluster have registered in the ELB, Terraform will begin to undeploy the old ASG, first by deregistering the servers in that ASG from the ELB, and then by shutting them down (Figure 5-4).




*Figure 5-4. The servers in the old ASG begin to shut down*

After a minute or two, the old ASG will be gone, and you will be left with just v2 of your app running in the new ASG (Figure 5-5).



*Figure 5-5. Now, only the new ASG remains, which is running v2 of your code*

During this entire process, there are always servers running and handling requests from the ELB, so there is no downtime. Open the ELB URL in your browser and you should see something like Figure 5-6.



*Figure 5-6. The new code is now deployed*

Success! The new server text has deployed. As a fun experiment, make another change to the server\_text parameter (e.g., update it to say “foo bar”), and run the apply command. In a separate terminal tab, if you’re on Linux/Unix/OS X, you can use a Bash one-liner to run curl in a loop, hitting your ELB once per second, and allowing you to see the zero-downtime deployment in action:

> while true; do curl http://<load\_balancer\_url>; sleep 1; done

For the first minute or so, you should see the same response that says “New server text”. Then, you’ll start seeing it alternate between the “New server text” and “foo bar”. This means the new Instances have registered in the ELB. After another minute, the “New server text” will disappear, and you’ll only see “foo bar”, which means the old ASG has been shut down. The output will look something like this (for clarity, I’m listing only the contents of the <h1> tags):

New server text

New server text

New server text

New server text

New server text

New server text

foo bar

New server text

foo bar

New server text

foo bar

New server text

foo bar

New server text

foo bar

New server text

foo bar

foo bar

foo bar

foo bar

foo bar

foo bar

As an added bonus, if something went wrong during the deployment, Terraform will automatically roll back! For example, if there was a bug in v2 of your app and it failed to boot, then the Instances in the new ASG will not register with the ELB. Terraform will wait up to wait\_for\_capacity\_timeout (default is 10 minutes) for min\_elb\_capacity servers of the v2 ASG to register in the ELB, after which it will consider the deployment a failure, delete the v2 ASG, and exit with an error (meanwhile, v1 of your app continues to run just fine in the original ASG).

**Terraform Gotchas**

After going through all these tips and tricks, it’s worth taking a step back and pointing out a few gotchas, including those related to the loop, if-statement, and deployment techniques, as well as those related to more general problems that affect Terraform as a whole:

* Count has limitations
* Zero-downtime deployment has limitations
* Valid plans can fail
* Refactoring can be tricky
* Eventual consistency is consistent…eventually

**Count Has Limitations**

In the examples in this chapter, you made extensive use of the count parameter in loops and if-statements. This works well, but there is a significant limitation: you cannot use dynamic data in the count parameter. By “dynamic data,” I mean any data that is fetched from a provider (e.g., from a data source) or is only available after a resource has been created (e.g., an output attribute of a resource).

For example, imagine you wanted to deploy multiple EC2 Instances, and for some reason did not want to use an Auto Scaling Group to do it. The code might look something like this:

**resource** "aws\_instance" "example" {

count = 3

ami = "ami-40d28157"

instance\_type = "t2.micro"

}

What if you wanted to deploy one EC2 Instance per availability zone (AZ) in the current AWS region? You might be tempted to use the aws\_availability\_zones data source to retrieve the list of AZs and update the code as follows:

data "aws\_availability\_zones" "all" {}

**resource** "aws\_instance" "example" {

count = "${length(data.aws\_availability\_zones.all.names)}"

availability\_zone =

"${element(data.aws\_availability\_zones.all.names, count.index)}"

ami = "ami-40d28157"

instance\_type = "t2.micro"

}

This code uses the length interpolation function to set the count parameter to the number of available AZs, and the element interpolation function with count.index to set the availability\_zone parameter to a different AZ for each EC2 Instance. This is a perfectly reasonable approach, but unfortunately, if you run this code, you’ll get an error that looks like this:

aws\_instance.example:resource count can't reference resource variable:

data.aws\_availability\_zones.all.names

The cause is that Terraform tries to resolve all the count parameters *before* fetching any dynamic data. Therefore, it’s trying to parse ${length(data.aws\_availability\_zones.all.names)} as a number *before* it has fetched the list of AZs. This is an inherent limitation in Terraform’s design and, as of January 2017, it’s an [open issue](https://github.com/hashicorp/terraform/issues/3888) in the Terraform community.

For now, your only option is to manually look up how many AZs you have in your AWS region (every AWS account has access to different AZs, so check your [EC2 console](https://console.aws.amazon.com/ec2)) and hard-code the count parameter to that value:

**resource** "aws\_instance" "example" {

count = 3

availability\_zone =

"${element(data.aws\_availability\_zones.all.names, count.index)}"

ami = "ami-40d28157"

instance\_type = "t2.micro"

}

Alternatively, you can set the count parameter to a variable:

**resource** "aws\_instance" "example" {

count = "${var.num\_availability\_zones}"

availability\_zone =

"${element(data.aws\_availability\_zones.all.names, count.index)}"

ami = "ami-40d28157"

instance\_type = "t2.micro"

}

However, the value for that variable must also be hard-coded somewhere along the line (e.g., via a default defined with the variable or a value passed in via the command-line -var option) and not depend on any dynamic data:

**variable** "num\_availability\_zones" {

description = "The number of Availability Zones in the AWS region"

default = 3

}

**Zero-Downtime Deployment has Limitations**

Using create\_before\_destroy with an ASG is a great technique for zero-downtime deployment, but there is one limitation: it doesn’t work with auto scaling policies. Or, to be more accurate, it resets your ASG size back to its min\_size after each deployment, which can be a problem if you had used auto scaling policies to increase the number of running servers.

For example, the web server cluster module includes a couple of aws\_autoscaling\_schedule resources that increase the number of servers in the cluster from 2 to 10 at 9 a.m. If you ran a deployment at, say, 11 a.m., the replacement ASG would boot up with only 2 servers, rather than 10, and would stay that way until 9 a.m. the next day.

There are several possible workarounds, including:

* Change the recurrence parameter on the aws\_autoscaling\_schedule from 0 9 \* \* \*, which means “run at 9 a.m.”, to something like 0-59 9-17 \* \* \*, which means “run every minute from 9 a.m. to 5 p.m.” If the ASG already has 10 servers, rerunning this auto scaling policy will have no effect, which is just fine; and if the ASG was just deployed, then running this policy ensures that the ASG won’t be around for more than a minute before the number of Instances is increased to 10. This approach is a bit of a hack, and while it may work for scheduled auto scaling actions, it does not work for auto scaling policies triggered by load (e.g., “add two servers if CPU utilization is over 95%”).
* Create a custom script that uses the AWS API to figure out how many servers are running in the ASG before deployment, use that value as the desired\_capacity parameter of the ASG in the Terraform configurations, and then kick off the deployment. After the new ASG has booted, the script should remove the desired\_capacity parameter so that the auto scaling policies can control the size of the ASG. On the plus side, the replacement ASG will boot up with the same number of servers as the original, and this approach works with all types of auto scaling policies. The downside is that it requires a custom and somewhat complicated deployment script rather than pure Terraform code.

Ideally, Terraform would have first-class support for zero-downtime deployment, but as of January 2017, this is an [open issue](https://github.com/hashicorp/terraform/issues/1552) in the Terraform community.

**Valid Plans Can Fail**

Sometimes, you run the plan command and it shows you a perfectly valid-looking plan, but when you run apply, you’ll get an error. For example, try to add an aws\_iam\_user resource with the exact same name you used for the IAM user you created in [Chapter 2](https://www.safaribooksonline.com/library/view/terraform-up-and/9781491977071/ch02.html#an_intro_to_terraform_syntax):

**resource** "aws\_iam\_user" "existing\_user" {

*# You should change this to the username of an IAM user that already*

*# exists so you can practice using the terraform import command*

name = "yevgeniy.brikman"

}

If you now run the plan command, Terraform will show you a plan that looks reasonable:

+ aws\_iam\_user.existing\_user

arn: "<computed>"

force\_destroy: "false"

name: "yevgeniy.brikman"

path: "/"

unique\_id: "<computed>"

Plan: 1 to add, 0 to change, 0 to destroy.

If you run the apply command, you’ll get the following error:

Error applying plan:

\* aws\_iam\_user.existing\_user: Error creating IAM User yevgeniy.brikman:

EntityAlreadyExists: User with name yevgeniy.brikman already exists.

The problem, of course, is that an IAM user with that name already exists. This can happen not only with IAM users, but almost any resource. Perhaps someone created it manually or with a different set of Terraform configurations, but either way, some identifier is the same, and that leads to a conflict. There are many variations on this error, and Terraform newbies are often caught offguard by them.

The key realization is that terraform plan only looks at resources in its Terraform state file. If you create resources *out-of-band*—such as by manually clicking around the AWS console—they will not be in Terraform’s state file, and therefore, Terraform will not take them into account when you run the plan command. As a result, a valid-looking plan may still fail.

There are two main lessons to take away from this:

Once you start using Terraform, you should only use Terraform

Once a part of your infrastructure is managed by Terraform, you should never make changes manually to it. Otherwise, you not only set yourself up for weird Terraform errors, but you also void many of the benefits of using infrastructure as code in the first place, as that code will no longer be an accurate representation of your infrastructure.

If you have existing infrastructure, use the import command

If you created infrastructure before you started using Terraform, you can use the terraform import command to add that infrastructure to Terraform’s state file, so Terraform is aware of and can manage that infrastructure. The import command takes two arguments. The first argument is the “address” of the resource in your Terraform configuration files. This makes use of the same syntax as interpolations, such as TYPE.NAME (e.g., aws\_iam\_user.existing\_user). The second argument is a resource-specific ID that identifies the resource to import. For example, the ID for an aws\_iam\_user resource is the name of the user (e.g., yevgeniy.brikman) and the ID for an aws\_instance is the EC2 Instance ID (e.g., i-190e22e5). The documentation for each resource typically specifies how to import it at the bottom of the page.

For example, here is the import command you can use to sync the aws\_iam\_user you just added in your Terraform configurations with the IAM user you created back in [Chapter 2](https://www.safaribooksonline.com/library/view/terraform-up-and/9781491977071/ch02.html#an_intro_to_terraform_syntax) (obviously, you should replace “yevgeniy.brikman” with your own username in this command):

> terraform import aws\_iam\_user.existing\_user yevgeniy.brikman

Terraform will use the AWS API to find your IAM user and create an association in its state file between that user and the aws\_iam\_user.existing\_user resource in your Terraform configurations. From then on, when you run the plan command, Terraform will know that IAM user already exists and not try to create it again.

Note that if you have a lot of existing resources that you want to import into Terraform, writing the Terraform code for them from scratch and importing them one at a time can be painful, so you may want to look into a tool such as [Terraforming](http://terraforming.dtan4.net/), which can import both code and state from an AWS account automatically.

**Refactoring Can Be Tricky**

A common programming practice is *refactoring*, where you restructure the internal details of an existing piece of code without changing its external behavior. The goal is to improve the readability, maintainability, and general hygiene of the code. Refactoring is an essential coding practice that you should do regularly. However, when it comes to Terraform, or any infrastructure as code tool, you have to be careful about what defines the “external behavior” of a piece of code, or you will run into unexpected problems.

For example, a common refactoring practice is to rename a variable or a function to give it a clearer name. Many IDEs even have built-in support for refactoring and can rename the variable or function for you, automatically, across the entire codebase. While such a renaming is something you might do without thinking twice in a general-purpose programming language, you have to be very careful in how you do it in Terraform, or it could lead to an outage.

For example, the webserver-cluster module has an input variable named cluster\_name:

**variable** "cluster\_name" {

description = "The name to use for all the cluster resources"

}

Perhaps you start using this module for deploying microservices, and initially, you set your microservice’s name to foo. Later on, you decide you want to rename the service to bar. This may seem like a trivial change, but it may actually cause an outage.

That’s because the webserver-cluster module uses the cluster\_name variable in a number of resources, including the name parameters of the ELB and two security groups. If you change the name parameter of certain resources, Terraform will delete the old version of the resource and create a new version to replace it. If the resource you are deleting happens to be an ELB, there will be nothing to route traffic to your web server cluster until the new ELB boots up. Similarly, if the resource you are deleting happens to be a security group, your servers will reject all network traffic until the new security group is created.

Another refactor you may be tempted to do is to change a Terraform identifier. For example, consider the aws\_security\_group resource in the webserver-cluster module:

**resource** "aws\_security\_group" "instance" {

name = "${var.cluster\_name}-instance"

lifecycle {

create\_before\_destroy = **true**

}

}

The identifier for this resource is called instance. Perhaps you were doing a refactor and you thought it would be clearer to change this name to cluster\_instance. What’s the result? Yup, you guessed it: downtime.

Terraform associates each resource identifier with an identifier from the cloud provider, such as associating an iam\_user resource with an AWS IAM User ID or an aws\_instance resource with an AWS EC2 Instance ID. If you change the resource identifier, such as changing the aws\_security\_group identifier from instance to cluster\_instance, then as far as Terraform knows, you deleted the old resource and have added a completely new one. As a result, if you apply these changes, Terraform will delete the old security group and create a new one, and in the time period in between, your servers will reject all network traffic.

There are four main lessons you should take away from this discussion:

Always use the plan command

All of these gotchas can be caught by running the plan command, carefully scanning the output, and noticing that Terraform plans to delete a resource that you probably don’t want deleted.

Create before destroy

If you do want to replace a resource, then think carefully about whether its replacement should be created before you delete the original. If so, then you may be able to use create\_before\_destroy to make that happen. Alternatively, you can also accomplish the same effect through two manual steps: first, add the new resource to your configurations and run the apply command; second, remove the old resource from your configurations and run the apply command again.

All identifiers are immutable

Treat the identifiers you associate with each resource as immutable. If you change an identifier, Terraform will delete the old resource and create a new one to replace it. Therefore, don’t rename identifiers unless absolutely necessary, and even then, use the plan command, and consider whether you should use a create-before-destroy strategy.

Some parameters are immutable

The parameters of many resources are immutable, so if you change them, Terraform will delete the old resource and create a new one to replace it. The documentation for each resource often specifies what happens if you change a parameter, so RTFM. And, once again, make sure to always use the plan command, and consider whether you should use a create-before-destroy strategy.

**Eventual Consistency Is Consistent…Eventually**

The APIs for some cloud providers, such as AWS, are asynchronous and eventually consistent. *Asynchronous* means the API may send a response immediately, without waiting for the requested action to complete. *Eventually consistent* means it takes time for a change to propagate throughout the entire system, so for some period of time, you may get inconsistent responses depending on which data store replica happens to respond to your API calls.

For example, let’s say you make an API call to AWS asking it to create an EC2 Instance. The API will return a “success” (i.e., 201 Created) response more or less instantly, without waiting for the EC2 Instance creation to complete. If you tried to connect to that EC2 Instance immediately, you’d most likely fail because AWS is still provisioning it or the Instance hasn’t booted yet. Moreover, if you made another API call to fetch information about that EC2 Instance, you may get an error in return (i.e., 404 Not Found). That’s because the information about that EC2 Instance may still be propagating throughout AWS, and it’ll take a few seconds before it’s available everywhere.

In short, whenever you use an asynchronous and eventually consistent API, you are supposed to wait and retry for a while until that action has completed and propagated. Unfortunately, Terraform does not do a great job of this. As of version 0.8.x, Terraform still has a number of eventual consistency bugs that you will hit from time to time after running terraform apply.

For example, there is [#5335](https://github.com/hashicorp/terraform/issues/5335):

> terraform apply

aws\_route.internet-gateway:

error finding matching route for Route table (rtb-5ca64f3b)

and destination CIDR block (0.0.0.0/0)

And [#5185](https://github.com/hashicorp/terraform/issues/5185):

> terraform apply

Resource 'aws\_eip.nat' does not have attribute 'id' for variable 'aws\_eip.nat.id'

And [#6813](https://github.com/hashicorp/terraform/issues/6813):

> terraform apply

aws\_subnet.private-persistence.2: InvalidSubnetID.NotFound:

The subnet ID 'subnet-xxxxxxx' does not exist

These bugs are annoying, but fortunately, most of them are harmless. If you just rerun terraform apply, everything will work fine, since by the time you rerun it, the information has propagated throughout the system.

It’s also worth noting that eventual consistency bugs may be more likely if the place from where you’re running Terraform is geographically far away from the provider you’re using. For example, if you’re running Terraform on your laptop in California and you’re deploying code to the AWS region eu-west-1, which is thousands of miles away in Ireland, you are more likely to see eventual consistency bugs. I’m guessing this is because the API calls from Terraform get routed to a local AWS data center (e.g., us-west-1, which is in California), and the replicas in that data center take a longer time to update if the actual changes are happening in a different data center.

**Conclusion**

Although Terraform is a declarative language, it includes a large number of tools, such as variables and modules, which you saw in [Chapter 4](https://www.safaribooksonline.com/library/view/terraform-up-and/9781491977071/ch04.html#how_to_create_reusable_infrastructure), and count, create\_before\_destroy, and interpolation functions, which you saw in this chapter, that give the language a surprising amount of flexibility and expressive power. There are many permutations of the if-statement tricks shown in this chapter, so spend some time browsing the [interpolation documentation](https://www.terraform.io/docs/configuration/interpolation.html) and let your inner hacker go wild. OK, maybe not too wild, as someone still has to maintain your code, but just wild enough that you can create clean, beautiful APIs for your users.

These users will be the focus of the next chapter, which describes how to use Terraform as a team. This includes a discussion of what workflows you can use, how to manage environments, how to test your Terraform configurations, and more.

[1](https://www.safaribooksonline.com/library/view/terraform-up-and/9781491977071/ch05.html#idm140207901199520-marker) If the index is greater than the number of elements in list, the element function will automatically “wrap” around using a standard mod function.

[2](https://www.safaribooksonline.com/library/view/terraform-up-and/9781491977071/ch05.html#idm140207900413392-marker) You can learn about CPU credits here: *<http://amzn.to/2lTuvs5>*.

[3](https://www.safaribooksonline.com/library/view/terraform-up-and/9781491977071/ch05.html#idm140207899037600-marker) Credit for this technique goes to [Paul Hinze](http://bit.ly/2lksQgv).